ADO組件之分頁程式

應該來說，學會了如何插入記錄，如何顯示記錄，那麼現在簡單的完整的文章系統、新聞系統和留言系統不成問題。
那接著下面的問題就是：隨著資料內容的不段增加，單獨通過一張頁面顯示所有資料是不行也是很不理性的。
所以，解決的辦法就是採用分頁技術。

1，rs.RecordCount
很顯然，RecordCount就是用來顯示資料庫表中一共多少條記錄的，也可以形象地說表中一共有多少行。
經常用在分頁中就是一共有N篇文章等總計的資料顯示。

2，rs.PageSize
rs.PageSize也就是一頁的大小，也就表示一張ASP頁可以顯示記錄的條數。
值是自己定義的，比如經常看到的每頁顯示N篇文章之類的資料。

3，rs.AbsolutePage 和 rs.pagecount
說到分頁，一定不能不提到 rs.AbsolutePage 。
記錄集的AbsolutePage屬性最主要的作用就是決定著當前顯示的是第幾頁。
它的值是有依據的，指定了rs.PageSize，那麼rs.pagecount的資料值就是rs.RecordCount和rs.PageSize整除結果。
比如：
總資料記錄rs.RecordCount共20條，
每頁顯示條數rs.PageSize設為5條，
那麼頁數rs.pagecount數就是20/5=4頁次，
而rs.AbsolutePage則就只能是第1頁，第2頁……第4頁。

說到現在，弄個具體程式來測試一下。繼續對showit.asp進行修改如下：

<!--#include file="conn.asp" -->
<%
Set rs = Server.CreateObject ("ADODB.Recordset")
sql = "Select * from cnarticle order by cn_id desc"
rs.Open sql,conn,1,1

page=request.querystring("page")  'page值為接受值
rs.PageSize = 2 '每頁顯示記錄數
rs.AbsolutePage = Page '顯示當前頁等於接收的頁數
For i = 1 to rs.PageSize '利用for next 循環依次讀出當前頁的記錄
if rs.EOF then
  Exit For
end if
 response.write("<br>文章內容是:"& rs("cn_content"))
rs.MoveNext
next

rs.close
Set rs = Nothing
conn.close
set conn=nothing
%>
HERE，你測試的前提就是資料庫中的記錄相對要大於4條，這樣測試效果才明顯；
還有測試的方法就是在showit.asp後面添加?page=1或者?page=2等測試觀察網頁顯示效果。

其實，說到底，顯示資料庫內容就是

<%
For i = 1 to rs.PageSize
  if rs.EOF then
     Exit For 
  end if
  response.write("<br>文章內容是:"& rs("cn_content"))
  rs.MoveNext
next
%>
起的作用，但想像一下：該程式應該都只能顯示出2條資料（一直不變的2條資料）。
但為什麼加上?page=1和?page=2會顯示不同的結果呢？……那絕對就是rs.AbsolutePage的作用了。
這個搞清楚，相信分頁的整體架構就有點眉目了。

<!--#include file="conn.asp" -->
<%
Set rs = Server.CreateObject("ADODB.Recordset")
sql ="Select * from cnarticle"
rs.Open sql,conn,1,1

filepath=request.servervariables("path_info")
page=request.querystring("page")  'page值為接受值
rs.PageSize = 2 '每頁顯示記錄數
if Not IsEmpty(page) then '如果page已經初始化...   
   if Not IsNumeric(page) then '判斷page值是否為數字
      Page=1   
   else
      Page = cint(page) '接收page并化為數字型賦給page變量
   end if
   if Page > rs.PageCount then '如果接收的頁數大於總頁數
      rs.AbsolutePage = rs.PageCount '設置當前顯示頁等於最後頁
   elseif Page <= 0 then '如果page小於等於0
      rs.AbsolutePage = 1 '設置當前顯示頁等於第一頁
   else
     rs.AbsolutePage = Page '如果大於零,顯示當前頁等於接收的頁數
   end if
else
   rs.AbsolutePage=1
end if
Page = rs.AbsolutePage

For i = 1 to rs.PageSize '利用for next 循環依次讀出當前頁的記錄
   if rs.EOF then
      Exit For
   end if
   response.write("文章標題是:"& rs("cn_title"))
   response.write("<br>文章作者是:"& rs("cn_author"))
   response.write("<br>文章加入時間是:"& rs("cn_time"))
   response.write("<br>文章內容是:"& rs("cn_content"))
   response.write("<hr>")
   rs.MoveNextNext
%>
<form action="<%=filepath%>" method="get">
<!--首先保證總頁數不為1、不為0-->
<%if rs.pagecount<>1 and rs.pagecount<>0 then%>
     <!--如果當前頁數大於1，無論何時都應顯示首頁和上一頁的連結-->
     <%if page>1 then%>
     [<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
     [<a Href="<%=filepath%>?Page=<% = page -1 %>">上一頁</a>]
          <!--如果當前頁數大於1並且小於總頁面數時，顯示出尾頁和下一頁的連結-->
          <%if page<rs.pagecount then %>
               [<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
               [<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
          <!--如果當前頁數大于1並且仍大於或等於總頁面數時，不顯示出尾頁和下一頁的連結-->    
         <%else%>
               [下一頁] [尾頁]
         <%end if%>
         <!--否則，當前頁數不大於1，則只顯示尾頁和下一頁的連結-->
     <%else%>
     [首頁] [上一頁] [<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
     [<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
     <%end if %>
<!--最終，總頁數若為1、為0則沒有任何連結-->
<%else%>
[首頁] [上一頁] [下一頁] [尾頁]
<%end if%>
[頁次:<font color=red><b><%=page%></b></font>/<%=rs.PageCount%>]
[共<%=rs.RecordCount%>篇 <font color=red><b><%=rs.PageSize%></b></font>篇/頁]
轉到<input name="page" size=5 value="<%=page%>">頁
<input type="submit" value="Enter">
</form>
<%
rs.close
Set rs = Nothing
conn.close
set conn=Nothing
%>
長長的分頁代碼，搞懂是真不容易，平臺引用起來還需要修改也是比較麻煩。
最后能做成一個函數，下次調用起來就很方便了。

如要引用，則可以：

<%
call pagination(rs.PageCount,rs.pagesize,page,rs.RecordCount)
%>

 給當前日誌評分：

正在讀取評分資料...